Downgrading or Upgrading Packages

When working with Flakes, you may encounter situations where you need to downgrade or upgrade certain packages to address bugs or compatibility issues. In Flakes, package versions and hash values are directly tied to the git commit of their flake input. To modify the package version, you need to lock the git commit of the flake input.

Here's an example of how you can add multiple nixpkgs inputs, each using a different git commit or branch:

{
  description = "NixOS configuration of Ryan Yin";

  inputs = {
    # Default to the nixos-unstable branch
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    # Latest stable branch of nixpkgs, used for version rollback
    # The current latest version is 22.11
    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-22.11";

    # You can also use a specific git commit hash to lock the version
    nixpkgs-fd40cef8d.url = "github:nixos/nixpkgs/fd40cef8d797670e203a27a91e4b8e6decf0b90c";
  };

  outputs = inputs@{ self, nixpkgs, nixpkgs-stable, nixpkgs-fd40cef8d, ... }: {
    nixosConfigurations = {
      nixos-test = nixpkgs.lib.nixosSystem rec {
        system = "x86_64-linux";

        # The `specialArgs` parameter passes the non-default nixpkgs instances to other nix modules
        specialArgs = {
          # To use packages from nixpkgs-stable, we configure some parameters for it first
          pkgs-stable = import nixpkgs-stable {
            system = system;  # Refer to the `system` parameter from the outer scope recursively
            # To use Chrome, we need to allow the installation of non-free software
            config.allowUnfree = true;
          };
          pkgs-fd40cef8d = import nixpkgs-fd40cef8d {
            system = system;
            config.allowUnfree = true;
          };
        };

        modules = [
          ./hosts/nixos-test

          # Omit other configurations...
        ];
      };
    };
  };
}

In the above example, we have defined multiple nixpkgs inputs: nixpkgs, nixpkgs-stable, and nixpkgs-fd40cef8d. Each input corresponds to a different git commit or branch.

Next, you can refer to the packages from pkgs-stable or pkgs-fd40cef8d within your submodule. Here's an example of a Home Manager submodule:

{
  pkgs,
  config,
  # Nix will search for and inject this parameter from `specialArgs` in `flake.nix`
  pkgs-stable,
  # pkgs-fd40cef8d,
  ...
}:

{
  # Use packages from `pkgs-stable` instead of `pkgs`
  home.packages = with pkgs-stable; [
    firefox-wayland

    # Chrome Wayland support was broken on the nixos-unstable branch, so we fallback to the stable branch for now
    # Reference: https://github.com/swaywm/sway/issues/7562
    google-chrome
  ];

  programs.vscode = {
    enable

 = true;
    package = pkgs-stable.vscode;  # Refer to vscode from `pkgs-stable` instead of `pkgs`
  };
}

By adjusting the configuration as shown above, you can deploy it using sudo nixos-rebuild switch. This will downgrade your Firefox/Chrome/VSCode versions to the ones corresponding to nixpkgs-stable or nixpkgs-fd40cef8d.

According to 1000 instances of nixpkgs, it's not a good practice to use import in submodules to customize nixpkgs. Each import creates a new instance of nixpkgs, which increases build time and memory usage as the configuration grows. To avoid this problem, we create all nixpkgs instances in flake.nix.

3.4 KiB Raw Blame History

Downgrading or Upgrading Packages

3.4 KiB

Raw Blame History