mirror of
https://github.com/amix/vimrc
synced 2024-12-23 18:33:08 +00:00
0d8e7370bd
commentary: Comment stuff out. Use `gcc` to comment out a line (takes a count), `gc` to comment out the target of a motion (for example, `gcap` to comment out a paragraph), and `gc` in visual mode to comment out the selection. That's it.
75 lines
2.5 KiB
VimL
75 lines
2.5 KiB
VimL
" commentary.vim - Comment stuff out
|
|
" Maintainer: Tim Pope <http://tpo.pe/>
|
|
" Version: 1.1
|
|
" GetLatestVimScripts: 3695 1 :AutoInstall: commentary.vim
|
|
|
|
if exists("g:loaded_commentary") || &cp || v:version < 700
|
|
finish
|
|
endif
|
|
let g:loaded_commentary = 1
|
|
|
|
function! s:go(type,...) abort
|
|
if a:0
|
|
let [lnum1, lnum2] = [a:type, a:1]
|
|
else
|
|
let [lnum1, lnum2] = [line("'["), line("']")]
|
|
endif
|
|
|
|
let [l, r] = split(substitute(substitute(&commentstring,'\S\zs%s',' %s',''),'%s\ze\S','%s ',''),'%s',1)
|
|
let uncomment = 2
|
|
for lnum in range(lnum1,lnum2)
|
|
let line = matchstr(getline(lnum),'\S.*\s\@<!')
|
|
if line != '' && (stridx(line,l) || line[strlen(line)-strlen(r) : -1] != r)
|
|
let uncomment = 0
|
|
endif
|
|
endfor
|
|
|
|
for lnum in range(lnum1,lnum2)
|
|
let line = getline(lnum)
|
|
if strlen(r) > 2 && l.r !~# '\\'
|
|
let line = substitute(line,
|
|
\'\M'.r[0:-2].'\zs\d\*\ze'.r[-1:-1].'\|'.l[0].'\zs\d\*\ze'.l[1:-1],
|
|
\'\=substitute(submatch(0)+1-uncomment,"^0$\\|^-\\d*$","","")','g')
|
|
endif
|
|
if uncomment
|
|
let line = substitute(line,'\S.*\s\@<!','\=submatch(0)[strlen(l):-strlen(r)-1]','')
|
|
else
|
|
let line = substitute(line,'^\%('.matchstr(getline(lnum1),'^\s*').'\|\s*\)\zs.*\S\@<=','\=l.submatch(0).r','')
|
|
endif
|
|
call setline(lnum,line)
|
|
endfor
|
|
endfunction
|
|
|
|
function! s:undo()
|
|
let [l, r] = split(substitute(substitute(&commentstring,'\S\zs%s',' %s',''),'%s\ze\S','%s ',''),'%s',1)
|
|
let lnums = [line('.')+1, line('.')-2]
|
|
for [index, dir, bound, line] in [[0, -1, 1, ''], [1, 1, line('$'), '']]
|
|
while lnums[index] != bound && line ==# '' || !(stridx(line,l) || line[strlen(line)-strlen(r) : -1] != r)
|
|
let lnums[index] += dir
|
|
let line = matchstr(getline(lnums[index]+dir),'\S.*\s\@<!')
|
|
endwhile
|
|
endfor
|
|
call s:go(lnums[0], lnums[1])
|
|
silent! call repeat#set("\<Plug>CommentaryUndo")
|
|
endfunction
|
|
|
|
xnoremap <silent> <Plug>Commentary :<C-U>call <SID>go(line("'<"),line("'>"))<CR>
|
|
nnoremap <silent> <Plug>Commentary :<C-U>set opfunc=<SID>go<CR>g@
|
|
nnoremap <silent> <Plug>CommentaryLine :<C-U>set opfunc=<SID>go<Bar>exe 'norm! 'v:count1.'g@_'<CR>
|
|
nnoremap <silent> <Plug>CommentaryUndo :<C-U>call <SID>undo()<CR>
|
|
|
|
if !hasmapto('<Plug>Commentary') || maparg('gc','n') ==# ''
|
|
xmap gc <Plug>Commentary
|
|
nmap gc <Plug>Commentary
|
|
nmap gcc <Plug>CommentaryLine
|
|
nmap gcu <Plug>CommentaryUndo
|
|
endif
|
|
|
|
if maparg('\\','n') ==# '' && maparg('\','n') ==# ''
|
|
xmap \\ <Plug>Commentary
|
|
nmap \\ <Plug>Commentary
|
|
nmap \\\ <Plug>CommentaryLine
|
|
nmap \\u <Plug>CommentaryUndo
|
|
endif
|
|
|
|
" vim:set et sw=2:
|