mirror of
https://github.com/DarkFlippers/unleashed-firmware
synced 2024-11-10 15:04:19 +00:00
ed385594a3
* faploader: more subsystem headers in API table; not counting header entries for SDK version change * subghz: removed dead function * Adjusted API version * hal: removed furi_hal_power_get_system_voltage * lib: mbedtls: additional flags for .fap linkage * fbt: rebuilding assets when git commit id changes * fbt: removed assets rebuild on git commit id change; added explicit dependency for SDK source on compiled assets parts; removed unneeded sdk regeneration runs * fbt: changed stock plugins to EXTERNAL apps; restored building app as a PLUGIN as a part of main fw as well as a .fap; readme fixes * fbt: restored certain apps to PLUGIN type * fbt: app manifests: renamed version->fap_version, added extra fields * fbt: fixed version processing after rename Co-authored-by: あく <alleteam@gmail.com>
97 lines
2.3 KiB
Text
97 lines
2.3 KiB
Text
Import("ENV")
|
|
|
|
|
|
from fbt.appmanifest import FlipperAppType
|
|
|
|
appenv = ENV.Clone(
|
|
tools=[("fbt_extapps", {"EXT_APPS_WORK_DIR": ENV.subst("${BUILD_DIR}/.extapps")})]
|
|
)
|
|
|
|
appenv.Replace(
|
|
LINKER_SCRIPT="application-ext",
|
|
)
|
|
|
|
appenv.AppendUnique(
|
|
CCFLAGS=[
|
|
"-ggdb3",
|
|
"-mword-relocations",
|
|
"-mlong-calls",
|
|
"-fno-common",
|
|
"-nostdlib",
|
|
"-fvisibility=hidden",
|
|
],
|
|
LINKFLAGS=[
|
|
"-Ur",
|
|
"-Wl,-Ur",
|
|
# "-Wl,--orphan-handling=error",
|
|
"-Bsymbolic",
|
|
"-nostartfiles",
|
|
"-mlong-calls",
|
|
"-fno-common",
|
|
"-nostdlib",
|
|
"-Wl,--gc-sections",
|
|
"-Wl,--no-export-dynamic",
|
|
"-fvisibility=hidden",
|
|
"-Wl,-e${APP_ENTRY}",
|
|
"-Xlinker",
|
|
"-Map=${TARGET}.map",
|
|
"-specs=nano.specs",
|
|
"-specs=nosys.specs",
|
|
],
|
|
LIBS=[
|
|
"m",
|
|
"gcc",
|
|
"stdc++",
|
|
"supc++",
|
|
],
|
|
)
|
|
|
|
|
|
extapps = appenv["_extapps"] = {
|
|
"compact": {},
|
|
"debug": {},
|
|
"validators": {},
|
|
"dist": {},
|
|
}
|
|
|
|
|
|
def build_app_as_external(env, appdef):
|
|
compact_elf, debug_elf, validator = env.BuildAppElf(appdef)
|
|
extapps["compact"][appdef.appid] = compact_elf
|
|
extapps["debug"][appdef.appid] = debug_elf
|
|
extapps["validators"][appdef.appid] = validator
|
|
extapps["dist"][appdef.appid] = (appdef.fap_category, compact_elf)
|
|
|
|
|
|
apps_to_build_as_faps = [
|
|
FlipperAppType.PLUGIN,
|
|
FlipperAppType.EXTERNAL,
|
|
]
|
|
if appenv["DEBUG_TOOLS"]:
|
|
apps_to_build_as_faps.append(FlipperAppType.DEBUG)
|
|
|
|
for apptype in apps_to_build_as_faps:
|
|
for app in appenv["APPBUILD"].get_apps_of_type(apptype, True):
|
|
build_app_as_external(appenv, app)
|
|
|
|
# Ugly access to global option
|
|
if extra_app_list := GetOption("extra_ext_apps"):
|
|
for extra_app in extra_app_list.split(","):
|
|
build_app_as_external(appenv, appenv["APPMGR"].get(extra_app))
|
|
|
|
|
|
if appenv["FORCE"]:
|
|
appenv.AlwaysBuild(extapps["compact"].values())
|
|
|
|
Alias(appenv["FIRMWARE_BUILD_CFG"] + "_extapps", extapps["compact"].values())
|
|
|
|
if appsrc := appenv.subst("$APPSRC"):
|
|
app_manifest, fap_file = appenv.GetExtAppFromPath(appsrc)
|
|
appenv.PhonyTarget(
|
|
"launch_app",
|
|
'${PYTHON3} scripts/runfap.py ${SOURCE} --fap_dst_dir "/ext/apps/${FAP_CATEGORY}"',
|
|
source=fap_file,
|
|
FAP_CATEGORY=app_manifest.fap_category,
|
|
)
|
|
|
|
Return("extapps")
|