mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-09-23 16:11:54 +00:00
99e2fbcb69
Rename the sections used to implement linker lists so they begin with '__u_boot_list' rather than '.u_boot_list'. The double underscore at the start is still distinct from the single underscore used by the symbol names. Having a '.' in the section names conflicts with clang's ASAN instrumentation which tries to add redzones between the linker list elements, causing expected accesses to fail. However, clang doesn't try to add redzones to user sections, which are names with all alphanumeric and underscore characters. Signed-off-by: Andrew Scull <ascull@google.com> Reviewed-by: Simon Glass <sjg@chromium.org>
83 lines
1.3 KiB
Text
83 lines
1.3 KiB
Text
/* SPDX-License-Identifier: BSD-2-Clause */
|
|
/*
|
|
* U-Boot EFI linker script
|
|
*
|
|
* Modified from usr/lib32/elf_x86_64_efi.lds in gnu-efi
|
|
*/
|
|
|
|
OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
|
|
OUTPUT_ARCH(i386:x86-64)
|
|
ENTRY(_start)
|
|
SECTIONS
|
|
{
|
|
image_base = .;
|
|
.hash : { *(.hash) } /* this MUST come first, EFI expects it */
|
|
. = ALIGN(4096);
|
|
.eh_frame : {
|
|
*(.eh_frame)
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
|
|
.text : {
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.gnu.linkonce.t.*)
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
|
|
.reloc : {
|
|
*(.reloc)
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
|
|
.data : {
|
|
*(.rodata*)
|
|
*(.got.plt)
|
|
*(.got)
|
|
*(.data*)
|
|
*(.sdata)
|
|
/* the EFI loader doesn't seem to like a .bss section, so we stick
|
|
* it all into .data: */
|
|
*(.sbss)
|
|
*(.scommon)
|
|
*(.dynbss)
|
|
*(.bss*)
|
|
*(COMMON)
|
|
*(.rel.local)
|
|
|
|
/* U-Boot lists and device tree */
|
|
. = ALIGN(8);
|
|
*(SORT(__u_boot_list*));
|
|
. = ALIGN(8);
|
|
*(.dtb*);
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
.dynamic : { *(.dynamic) }
|
|
. = ALIGN(4096);
|
|
|
|
.rela : {
|
|
*(.rela.data*)
|
|
*(.rela.got)
|
|
*(.rela.stab)
|
|
*(.rela__u_boot_list*)
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
.dynsym : { *(.dynsym) }
|
|
. = ALIGN(4096);
|
|
.dynstr : { *(.dynstr) }
|
|
. = ALIGN(4096);
|
|
|
|
/DISCARD/ : { *(.eh_frame) }
|
|
|
|
.ignored.reloc : {
|
|
*(.rela.reloc)
|
|
*(.note.GNU-stack)
|
|
}
|
|
|
|
.comment 0 : { *(.comment) }
|
|
}
|