mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-11-26 14:40:41 +00:00
ef123c5253
Refactor linker-generated array code so that symbols which were previously linker-generated are now compiler- generated. This causes relocation records of type R_ARM_ABS32 to become R_ARM_RELATIVE, which makes code which uses LGA able to run before relocation as well as after. Note: this affects more than ARM targets, as linker- lists span possibly all target architectures, notably PowerPC. Conflicts: arch/arm/cpu/arm926ejs/mxs/u-boot-spl.lds arch/arm/cpu/arm926ejs/spear/u-boot-spl.lds arch/arm/cpu/armv7/omap-common/u-boot-spl.lds board/ait/cam_enc_4xx/u-boot-spl.lds board/davinci/da8xxevm/u-boot-spl-da850evm.lds board/davinci/da8xxevm/u-boot-spl-hawk.lds board/vpac270/u-boot-spl.lds Signed-off-by: Albert ARIBAUD <albert.u.boot@aribaud.net>
108 lines
2.5 KiB
Text
108 lines
2.5 KiB
Text
/*
|
|
* (C) Copyright 2000-2010
|
|
* Wolfgang Denk, DENX Software Engineering, wd@denx.de.
|
|
*
|
|
* See file CREDITS for list of people who contributed to this
|
|
* project.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License as
|
|
* published by the Free Software Foundation; either version 2 of
|
|
* the License, or (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
|
|
* MA 02111-1307 USA
|
|
*/
|
|
|
|
OUTPUT_ARCH(powerpc)
|
|
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
. = + SIZEOF_HEADERS;
|
|
.text :
|
|
{
|
|
/* WARNING - the following is hand-optimized to fit within */
|
|
/* the sector layout of our flash chips! XXX FIXME XXX */
|
|
|
|
arch/powerpc/cpu/mpc8xx/start.o (.text*)
|
|
arch/powerpc/cpu/mpc8xx/traps.o (.text*)
|
|
|
|
lib/libgeneric.o (.text*)
|
|
net/libnet.o (.text*)
|
|
arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
|
|
arch/powerpc/lib/libpowerpc.o (.text*)
|
|
|
|
. = env_offset;
|
|
common/env_embedded.o (.text*)
|
|
|
|
*(.text*)
|
|
}
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
.rodata :
|
|
{
|
|
*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
|
|
}
|
|
|
|
/* Read-write section, merged into data segment: */
|
|
. = (. + 0x00FF) & 0xFFFFFF00;
|
|
_erotext = .;
|
|
PROVIDE (erotext = .);
|
|
.reloc :
|
|
{
|
|
_GOT2_TABLE_ = .;
|
|
KEEP(*(.got2))
|
|
KEEP(*(.got))
|
|
PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
|
|
_FIXUP_TABLE_ = .;
|
|
KEEP(*(.fixup))
|
|
}
|
|
__got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
|
|
__fixup_entries = (. - _FIXUP_TABLE_)>>2;
|
|
|
|
.data :
|
|
{
|
|
*(.data*)
|
|
*(.sdata*)
|
|
}
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
|
|
. = .;
|
|
|
|
. = ALIGN(4);
|
|
.u_boot_list : {
|
|
KEEP(*(SORT(.u_boot_list*)));
|
|
}
|
|
|
|
. = .;
|
|
__start___ex_table = .;
|
|
__ex_table : { *(__ex_table) }
|
|
__stop___ex_table = .;
|
|
|
|
. = ALIGN(256);
|
|
__init_begin = .;
|
|
.text.init : { *(.text.init) }
|
|
.data.init : { *(.data.init) }
|
|
. = ALIGN(256);
|
|
__init_end = .;
|
|
|
|
__bss_start = .;
|
|
.bss (NOLOAD) :
|
|
{
|
|
*(.bss*)
|
|
*(.sbss*)
|
|
*(COMMON)
|
|
. = ALIGN(4);
|
|
}
|
|
__bss_end__ = . ;
|
|
PROVIDE (end = .);
|
|
}
|