mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-11-14 08:57:58 +00:00
077e1958ca
Add a parameter to the 32-bit entry to indicate if entry is from Real Mode or not. If entry is from Real Mode, execute the destructive 'sizer' routine to determine memory size as we are booting cold and running in Flash. If not entering from Real Mode, we are executing a U-Boot image from RAM and therefore the memory size is already known (and running 'sizer' will destroy the running image) There are now two 32-bit entry points. The first is the 'in RAM' entry point which exists at the start of the U-Boot binary image. As such, you can load u-boot.bin in RAM and jump directly to the load address without needing to calculate any offsets. The second entry point is used by the real-to-protected mode switch This patch also changes TEXT_BASE to 0x6000000 (in RAM). You can load the resulting image at 0x6000000 and simple go 0x6000000 from the u-boot prompt Hopefully a later patch will completely elliminate any dependency on TEXT_BASE like a relocatable linux kernel (perfect world) Signed-off-by: Graeme Russ <graeme.russ@gmail.com>
109 lines
2.8 KiB
Text
109 lines
2.8 KiB
Text
/*
|
|
* (C) Copyright 2002
|
|
* Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
|
|
*
|
|
* See file CREDITS for list of people who contributed to this
|
|
* project.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License as
|
|
* published by the Free Software Foundation; either version 2 of
|
|
* the License, or (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
|
|
* MA 02111-1307 USA
|
|
*/
|
|
|
|
OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
|
|
OUTPUT_ARCH(i386)
|
|
ENTRY(_start)
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0x06000000; /* Location of bootcode in flash */
|
|
_i386boot_text_start = .;
|
|
.text : { *(.text); }
|
|
|
|
. = ALIGN(4);
|
|
.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
|
|
|
|
_i386boot_text_size = SIZEOF(.text) + SIZEOF(.rodata);
|
|
. = ALIGN(4);
|
|
|
|
.data : { *(.data) }
|
|
. = ALIGN(4);
|
|
|
|
.interp : { *(.interp) }
|
|
. = ALIGN(4);
|
|
|
|
.dynsym : { *(.dynsym) }
|
|
. = ALIGN(4);
|
|
|
|
.dynstr : { *(.dynstr) }
|
|
. = ALIGN(4);
|
|
|
|
.hash : { *(.hash) }
|
|
. = ALIGN(4);
|
|
|
|
.got : { *(.got) }
|
|
. = ALIGN(4);
|
|
|
|
.got.plt : { *(.got.plt) }
|
|
. = ALIGN(4);
|
|
|
|
.dynamic (NOLOAD) : { *(.dynamic) }
|
|
. = ALIGN(4);
|
|
|
|
__u_boot_cmd_start = .;
|
|
.u_boot_cmd : { *(.u_boot_cmd) }
|
|
. = ALIGN(4);
|
|
__u_boot_cmd_end = .;
|
|
_i386boot_cmd_start = LOADADDR(.u_boot_cmd);
|
|
|
|
_i386boot_rel_dyn_start = .;
|
|
.rel.dyn : { *(.rel.dyn) }
|
|
_i386boot_rel_dyn_end = .;
|
|
|
|
. = ALIGN(4);
|
|
_i386boot_bss_start = ABSOLUTE(.);
|
|
.bss (NOLOAD) : { *(.bss) }
|
|
_i386boot_bss_size = SIZEOF(.bss);
|
|
|
|
/* 16bit realmode trampoline code */
|
|
.realmode 0x7c0 : AT ( LOADADDR(.rel.dyn) + SIZEOF(.rel.dyn) ) { *(.realmode) }
|
|
|
|
_i386boot_realmode = LOADADDR(.realmode);
|
|
_i386boot_realmode_size = SIZEOF(.realmode);
|
|
|
|
/* 16bit BIOS emulation code (just enough to boot Linux) */
|
|
.bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { *(.bios) }
|
|
|
|
_i386boot_bios = LOADADDR(.bios);
|
|
_i386boot_bios_size = SIZEOF(.bios);
|
|
|
|
/* The load addresses below assumes that the flash
|
|
* will be mapped so that 0x387f0000 == 0xffff0000
|
|
* at reset time
|
|
*
|
|
* The fe00 and ff00 offsets of the start32 and start16
|
|
* segments are arbitrary, the just have to be mapped
|
|
* at reset and the code have to fit.
|
|
* The fff0 offset of resetvec is important, however.
|
|
*/
|
|
. = 0xfffffe00;
|
|
.start32 : AT (0x0603fe00) { *(.start32); }
|
|
|
|
. = 0xf800;
|
|
.start16 : AT (0x0603f800) { *(.start16); }
|
|
|
|
. = 0xfff0;
|
|
.resetvec : AT (0x0603fff0) { *(.resetvec); }
|
|
_i386boot_end = (LOADADDR(.resetvec) + SIZEOF(.resetvec) );
|
|
}
|