mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-11-17 18:28:55 +00:00
c11528083e
The recent change to move the .bss outside of the image gives older binutils (ld from eldk4.1/binutils-2.16) some headache: ppc_85xx-ld: u-boot: Not enough room for program headers (allocated 3, need 4) ppc_85xx-ld: final link failed: Bad value We workaround it by being explicit about the program headers and not assigning the .bss to a program header. Signed-off-by: Kumar Gala <galak@kernel.crashing.org>
145 lines
3.3 KiB
Text
145 lines
3.3 KiB
Text
/*
|
|
* Copyright 2004-2008 Freescale Semiconductor, Inc.
|
|
*
|
|
* See file CREDITS for list of people who contributed to this
|
|
* project.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License as
|
|
* published by the Free Software Foundation; either version 2 of
|
|
* the License, or (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
|
|
* MA 02111-1307 USA
|
|
*/
|
|
|
|
OUTPUT_ARCH(powerpc)
|
|
/* Do we need any of these for elf?
|
|
__DYNAMIC = 0; */
|
|
PHDRS
|
|
{
|
|
text PT_LOAD;
|
|
bss PT_LOAD;
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
. = + SIZEOF_HEADERS;
|
|
.interp : { *(.interp) }
|
|
.hash : { *(.hash) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.rel.text : { *(.rel.text) }
|
|
.rela.text : { *(.rela.text) }
|
|
.rel.data : { *(.rel.data) }
|
|
.rela.data : { *(.rela.data) }
|
|
.rel.rodata : { *(.rel.rodata) }
|
|
.rela.rodata : { *(.rela.rodata) }
|
|
.rel.got : { *(.rel.got) }
|
|
.rela.got : { *(.rela.got) }
|
|
.rel.ctors : { *(.rel.ctors) }
|
|
.rela.ctors : { *(.rela.ctors) }
|
|
.rel.dtors : { *(.rel.dtors) }
|
|
.rela.dtors : { *(.rela.dtors) }
|
|
.rel.bss : { *(.rel.bss) }
|
|
.rela.bss : { *(.rela.bss) }
|
|
.rel.plt : { *(.rel.plt) }
|
|
.rela.plt : { *(.rela.plt) }
|
|
.init : { *(.init) }
|
|
.plt : { *(.plt) }
|
|
.text :
|
|
{
|
|
*(.text)
|
|
*(.fixup)
|
|
*(.got1)
|
|
} :text
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
.rodata :
|
|
{
|
|
*(.rodata)
|
|
*(.rodata1)
|
|
*(.rodata.str1.4)
|
|
*(.eh_frame)
|
|
} :text
|
|
.fini : { *(.fini) } =0
|
|
.ctors : { *(.ctors) }
|
|
.dtors : { *(.dtors) }
|
|
|
|
/* Read-write section, merged into data segment: */
|
|
. = (. + 0x00FF) & 0xFFFFFF00;
|
|
_erotext = .;
|
|
PROVIDE (erotext = .);
|
|
.reloc :
|
|
{
|
|
*(.got)
|
|
_GOT2_TABLE_ = .;
|
|
*(.got2)
|
|
_FIXUP_TABLE_ = .;
|
|
*(.fixup)
|
|
}
|
|
__got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
|
|
__fixup_entries = (. - _FIXUP_TABLE_) >> 2;
|
|
|
|
.data :
|
|
{
|
|
*(.data)
|
|
*(.data1)
|
|
*(.sdata)
|
|
*(.sdata2)
|
|
*(.dynamic)
|
|
CONSTRUCTORS
|
|
}
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
|
|
. = .;
|
|
__u_boot_cmd_start = .;
|
|
.u_boot_cmd : { *(.u_boot_cmd) }
|
|
__u_boot_cmd_end = .;
|
|
|
|
. = .;
|
|
__start___ex_table = .;
|
|
__ex_table : { *(__ex_table) }
|
|
__stop___ex_table = .;
|
|
|
|
. = ALIGN(256);
|
|
__init_begin = .;
|
|
.text.init : { *(.text.init) }
|
|
.data.init : { *(.data.init) }
|
|
. = ALIGN(256);
|
|
__init_end = .;
|
|
|
|
.bootpg ADDR(.text) + 0x7f000 :
|
|
{
|
|
cpu/mpc85xx/start.o (.bootpg)
|
|
} :text = 0xffff
|
|
|
|
.resetvec ADDR(.text) + 0x7fffc :
|
|
{
|
|
*(.resetvec)
|
|
} :text = 0xffff
|
|
|
|
. = ADDR(.text) + 0x80000;
|
|
|
|
__bss_start = .;
|
|
.bss (NOLOAD) :
|
|
{
|
|
*(.sbss) *(.scommon)
|
|
*(.dynbss)
|
|
*(.bss)
|
|
*(COMMON)
|
|
} :bss
|
|
|
|
. = ALIGN(4);
|
|
_end = . ;
|
|
PROVIDE (end = .);
|
|
}
|