mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-12-12 14:23:00 +00:00
86b9c3e4e4
At present U-Boot environment variables, and thus scripts, are defined by CONFIG_EXTRA_ENV_SETTINGS. It is painful to add large amounts of text to this file and dealing with quoting and newlines is harder than it should be. It would be better if we could just type the script into a text file and have it included by U-Boot. Add a feature that brings in a .env file associated with the board config, if present. To use it, create a file in a board/<vendor> directory, typically called <board>.env and controlled by the CONFIG_ENV_SOURCE_FILE option. The environment variables should be of the form "var=value". Values can extend to multiple lines. See the README under 'Environment Variables:' for more information and an example. In many cases environment variables need access to the U-Boot CONFIG variables to select different options. Enable this so that the environment scripts can be as useful as the ones currently in the board config files. This uses the C preprocessor, means that comments can be included in the environment using /* ... */ Also support += to allow variables to be appended to. This is needed when using the preprocessor. Signed-off-by: Simon Glass <sjg@chromium.org> Reviewed-by: Marek Behún <marek.behun@nic.cz> Tested-by: Marek Behún <marek.behun@nic.cz>
80 lines
1.8 KiB
Awk
80 lines
1.8 KiB
Awk
# SPDX-License-Identifier: GPL-2.0+
|
|
#
|
|
# Copyright 2021 Google, Inc
|
|
#
|
|
# SPDX-License-Identifier: GPL-2.0+
|
|
#
|
|
# Awk script to parse a text file containing an environment and convert it
|
|
# to a C string which can be compiled into U-Boot.
|
|
|
|
# The resulting output is:
|
|
#
|
|
# #define CONFIG_EXTRA_ENV_TEXT "<environment here>"
|
|
#
|
|
# If the input is empty, this script outputs a comment instead.
|
|
|
|
BEGIN {
|
|
# env holds the env variable we are currently processing
|
|
env = "";
|
|
ORS = ""
|
|
}
|
|
|
|
# Skip empty lines, as these are generated by the clang preprocessor
|
|
NF {
|
|
# Quote quotes
|
|
gsub("\"", "\\\"")
|
|
|
|
# Is this the start of a new environment variable?
|
|
if (match($0, "^([^ \t=][^ =]*)=(.*)$", arr)) {
|
|
if (length(env) != 0) {
|
|
# Record the value of the variable now completed
|
|
vars[var] = env
|
|
}
|
|
var = arr[1]
|
|
env = arr[2]
|
|
|
|
# Deal with += which concatenates the new string to the existing
|
|
# variable
|
|
if (length(env) != 0 && match(var, "^(.*)[+]$", var_arr))
|
|
{
|
|
# Allow var\+=val to indicate that the variable name is
|
|
# var+ and this is not actually a concatenation
|
|
if (substr(var_arr[1], length(var_arr[1])) == "\\") {
|
|
# Drop the backslash
|
|
sub(/\\[+]$/, "+", var)
|
|
} else {
|
|
var = var_arr[1]
|
|
env = vars[var] env
|
|
}
|
|
}
|
|
} else {
|
|
# Change newline to space
|
|
gsub(/^[ \t]+/, "")
|
|
|
|
# Don't keep leading spaces generated by the previous blank line
|
|
if (length(env) == 0) {
|
|
env = $0
|
|
} else {
|
|
env = env " " $0
|
|
}
|
|
}
|
|
}
|
|
|
|
END {
|
|
# Record the value of the variable now completed. If the variable is
|
|
# empty it is not set.
|
|
if (length(env) != 0) {
|
|
vars[var] = env
|
|
}
|
|
|
|
if (length(vars) != 0) {
|
|
printf("%s", "#define CONFIG_EXTRA_ENV_TEXT \"")
|
|
|
|
# Print out all the variables
|
|
for (var in vars) {
|
|
env = vars[var]
|
|
print var "=" vars[var] "\\0"
|
|
}
|
|
print "\"\n"
|
|
}
|
|
}
|