mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-09-24 08:22:14 +00:00
99e2fbcb69
Rename the sections used to implement linker lists so they begin with '__u_boot_list' rather than '.u_boot_list'. The double underscore at the start is still distinct from the single underscore used by the symbol names. Having a '.' in the section names conflicts with clang's ASAN instrumentation which tries to add redzones between the linker list elements, causing expected accesses to fail. However, clang doesn't try to add redzones to user sections, which are names with all alphanumeric and underscore characters. Signed-off-by: Andrew Scull <ascull@google.com> Reviewed-by: Simon Glass <sjg@chromium.org>
94 lines
1.7 KiB
Text
94 lines
1.7 KiB
Text
// SPDX-License-Identifier: GPL-2.0+
|
|
/*
|
|
* (C) Copyright 2019
|
|
* Rockchip Electronics Co., Ltd
|
|
* Kever Yang<kever.yang@rock-chips.com>
|
|
*
|
|
* (C) Copyright 2013
|
|
* David Feng <fenghua@phytium.com.cn>
|
|
*
|
|
* (C) Copyright 2002
|
|
* Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
|
|
*
|
|
* (C) Copyright 2010
|
|
* Texas Instruments, <www.ti.com>
|
|
* Aneesh V <aneesh@ti.com>
|
|
*/
|
|
|
|
OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
|
|
OUTPUT_ARCH(aarch64)
|
|
ENTRY(_start)
|
|
SECTIONS
|
|
{
|
|
. = 0x00000000;
|
|
|
|
.text : {
|
|
. = ALIGN(8);
|
|
*(.__image_copy_start)
|
|
CPUDIR/start.o (.text*)
|
|
*(.text*)
|
|
}
|
|
|
|
.rodata : {
|
|
. = ALIGN(8);
|
|
*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
|
|
}
|
|
|
|
.data : {
|
|
. = ALIGN(8);
|
|
*(.data*)
|
|
}
|
|
|
|
__u_boot_list : {
|
|
. = ALIGN(8);
|
|
KEEP(*(SORT(__u_boot_list*)));
|
|
}
|
|
|
|
.image_copy_end : {
|
|
. = ALIGN(8);
|
|
*(.__image_copy_end)
|
|
}
|
|
|
|
.end : {
|
|
. = ALIGN(8);
|
|
*(.__end)
|
|
}
|
|
|
|
_image_binary_end = .;
|
|
|
|
.bss_start (NOLOAD) : {
|
|
. = ALIGN(8);
|
|
KEEP(*(.__bss_start));
|
|
}
|
|
|
|
.bss (NOLOAD) : {
|
|
*(.bss*)
|
|
. = ALIGN(8);
|
|
}
|
|
|
|
.bss_end (NOLOAD) : {
|
|
KEEP(*(.__bss_end));
|
|
}
|
|
|
|
/DISCARD/ : { *(.dynsym) }
|
|
/DISCARD/ : { *(.dynstr*) }
|
|
/DISCARD/ : { *(.dynamic*) }
|
|
/DISCARD/ : { *(.plt*) }
|
|
/DISCARD/ : { *(.interp*) }
|
|
/DISCARD/ : { *(.gnu*) }
|
|
}
|
|
|
|
#if defined(CONFIG_TPL_MAX_SIZE)
|
|
ASSERT(__image_copy_end - __image_copy_start < (CONFIG_TPL_MAX_SIZE), \
|
|
"TPL image too big");
|
|
#endif
|
|
|
|
#if defined(CONFIG_TPL_BSS_MAX_SIZE)
|
|
ASSERT(__bss_end - __bss_start < (CONFIG_TPL_BSS_MAX_SIZE), \
|
|
"TPL image BSS too big");
|
|
#endif
|
|
|
|
#if defined(CONFIG_TPL_MAX_FOOTPRINT)
|
|
ASSERT(__bss_end - _start < (CONFIG_TPL_MAX_FOOTPRINT), \
|
|
"TPL image plus BSS too big");
|
|
#endif
|