mirror of
https://github.com/AsahiLinux/u-boot
synced 2024-12-13 14:53:06 +00:00
99e2fbcb69
Rename the sections used to implement linker lists so they begin with '__u_boot_list' rather than '.u_boot_list'. The double underscore at the start is still distinct from the single underscore used by the symbol names. Having a '.' in the section names conflicts with clang's ASAN instrumentation which tries to add redzones between the linker list elements, causing expected accesses to fail. However, clang doesn't try to add redzones to user sections, which are names with all alphanumeric and underscore characters. Signed-off-by: Andrew Scull <ascull@google.com> Reviewed-by: Simon Glass <sjg@chromium.org>
48 lines
886 B
Text
48 lines
886 B
Text
/* SPDX-License-Identifier: GPL-2.0+ */
|
|
/*
|
|
* (C) Copyright 2018
|
|
* Icenowy Zheng <icenowy@aosc.io>
|
|
*
|
|
* Based on arch/arm/cpu/armv7/sunxi/u-boot-spl.lds:
|
|
*/
|
|
MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE,\
|
|
LENGTH = CONFIG_SPL_MAX_SIZE }
|
|
MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
|
|
LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
|
|
|
|
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
|
|
OUTPUT_ARCH(arm)
|
|
ENTRY(_start)
|
|
SECTIONS
|
|
{
|
|
.text :
|
|
{
|
|
__start = .;
|
|
*(.vectors)
|
|
*(.text*)
|
|
} > .sram
|
|
|
|
. = ALIGN(4);
|
|
.rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
|
|
|
|
. = ALIGN(4);
|
|
.data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
|
|
|
|
. = ALIGN(4);
|
|
__u_boot_list : {
|
|
KEEP(*(SORT(__u_boot_list*)));
|
|
} > .sram
|
|
|
|
. = ALIGN(4);
|
|
__image_copy_end = .;
|
|
_end = .;
|
|
|
|
.bss :
|
|
{
|
|
. = ALIGN(4);
|
|
__bss_start = .;
|
|
*(.bss*)
|
|
. = ALIGN(4);
|
|
__bss_end = .;
|
|
} > .sdram
|
|
}
|