mirror of
https://github.com/nix-community/naersk
synced 2024-09-20 14:11:53 +00:00
94beb7a3ed
During compilation, we build two derivations - one for the dependencies and another for the user's crate itself. Passing `postInstall` to `buildPackage` pass-throughs it into both derivations, which is not what most users would probably expect. This commit adds `postInstall` as an explicit configuration option (so that it's neatly documented), zeroing it out for the dependencies-only derivation. I don't think there's any use case for something like `postInstallDeps`, so it's not introduced here. Closes https://github.com/nix-community/naersk/issues/237
76 lines
2 KiB
Nix
76 lines
2 KiB
Nix
{ cargo
|
|
, darwin
|
|
, fetchurl
|
|
, jq
|
|
, lib
|
|
, lndir
|
|
, remarshal
|
|
, rsync
|
|
, runCommand
|
|
, rustc
|
|
, stdenv
|
|
, writeText
|
|
, zstd
|
|
}@defaultBuildAttrs:
|
|
|
|
let
|
|
libb = import ./lib.nix { inherit lib writeText runCommand remarshal; };
|
|
|
|
builtinz = builtins // import ./builtins
|
|
{ inherit lib writeText remarshal runCommand; };
|
|
|
|
mkConfig = arg:
|
|
import ./config.nix { inherit lib arg libb builtinz; };
|
|
|
|
buildPackage = arg:
|
|
let
|
|
config = mkConfig arg;
|
|
gitDependencies =
|
|
libb.findGitDependencies { inherit (config) cargolock gitAllRefs gitSubmodules; };
|
|
cargoconfig =
|
|
if builtinz.pathExists (toString config.root + "/.cargo/config")
|
|
then builtins.readFile (config.root + "/.cargo/config")
|
|
else null;
|
|
build = args: import ./build.nix (
|
|
{
|
|
inherit gitDependencies;
|
|
version = config.packageVersion;
|
|
} // config.buildConfig // defaultBuildAttrs // args
|
|
);
|
|
|
|
# the dependencies from crates.io
|
|
buildDeps =
|
|
build
|
|
{
|
|
pname = "${config.packageName}-deps";
|
|
src = libb.dummySrc {
|
|
inherit cargoconfig;
|
|
inherit (config) cargolock cargotomls copySources copySourcesFrom;
|
|
};
|
|
inherit (config) userAttrs;
|
|
# TODO: custom cargoTestCommands should not be needed here
|
|
cargoTestCommands = map (cmd: "${cmd} || true") config.buildConfig.cargoTestCommands;
|
|
copyTarget = true;
|
|
copyBins = false;
|
|
copyBinsFilter = ".";
|
|
copyDocsToSeparateOutput = false;
|
|
postInstall = false;
|
|
builtDependencies = [];
|
|
};
|
|
|
|
# the top-level build
|
|
buildTopLevel =
|
|
let
|
|
drv =
|
|
build
|
|
{
|
|
pname = config.packageName;
|
|
inherit (config) userAttrs src;
|
|
builtDependencies = lib.optional (! config.isSingleStep) buildDeps;
|
|
};
|
|
in
|
|
drv.overrideAttrs config.overrideMain;
|
|
in
|
|
buildTopLevel;
|
|
in
|
|
{ inherit buildPackage; }
|