mirror of
https://github.com/nix-community/home-manager
synced 2024-11-23 05:03:09 +00:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.targets.darwin;
|
|
homeDir = config.home.homeDirectory;
|
|
confFile = pkgs.writeText "DefaultKeybinding.dict"
|
|
(lib.generators.toPlist { } cfg.keybindings);
|
|
in {
|
|
options.targets.darwin.keybindings = mkOption {
|
|
type = with types; attrsOf anything;
|
|
default = { };
|
|
example = {
|
|
"^u" = "deleteToBeginningOfLine:";
|
|
"^w" = "deleteWordBackward:";
|
|
};
|
|
description = ''
|
|
This will configure the default keybindings for text fields in macOS
|
|
applications. See
|
|
[Apple's documentation](https://developer.apple.com/library/archive/documentation/Cocoa/Conceptual/EventOverview/TextDefaultsBindings/TextDefaultsBindings.html)
|
|
for more details.
|
|
|
|
::: {.warning}
|
|
Existing keybinding configuration will be wiped when using this
|
|
option.
|
|
:::
|
|
'';
|
|
};
|
|
|
|
config = mkIf (cfg.keybindings != { }) {
|
|
assertions = [
|
|
(hm.assertions.assertPlatform "targets.darwin.keybindings" pkgs
|
|
platforms.darwin)
|
|
];
|
|
|
|
# NOTE: just copy the files because symlinks won't be recognized by macOS
|
|
home.activation.setCocoaKeybindings =
|
|
hm.dag.entryAfter [ "writeBoundary" ] ''
|
|
$VERBOSE_ECHO "Configuring keybindings for the Cocoa Text System"
|
|
$DRY_RUN_CMD install -Dm644 $VERBOSE_ARG \
|
|
"${confFile}" "${homeDir}/Library/KeyBindings/DefaultKeyBinding.dict"
|
|
'';
|
|
};
|
|
}
|