mirror of
https://github.com/nix-community/home-manager
synced 2024-11-23 13:13:26 +00:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
80 lines
2 KiB
Nix
80 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.rtx;
|
|
tomlFormat = pkgs.formats.toml { };
|
|
in {
|
|
meta.maintainers = [ hm.maintainers.pedorich-n ];
|
|
|
|
options = {
|
|
programs.rtx = {
|
|
enable =
|
|
mkEnableOption (lib.mdDoc "RTX. Runtime Executor (asdf Rust clone)");
|
|
|
|
package = mkPackageOptionMD pkgs "rtx" { };
|
|
|
|
enableBashIntegration = mkEnableOption (lib.mdDoc "Bash Integration") // {
|
|
default = true;
|
|
};
|
|
|
|
enableZshIntegration = mkEnableOption (lib.mdDoc "Zsh Integration") // {
|
|
default = true;
|
|
};
|
|
|
|
enableFishIntegration = mkEnableOption (lib.mdDoc "Fish Integration") // {
|
|
default = true;
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
tools = {
|
|
node = "lts";
|
|
python = ["3.10" "3.11"];
|
|
};
|
|
|
|
settings = {
|
|
verbose = false;
|
|
experimental = false;
|
|
};
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Settings written to {file}`$XDG_CONFIG_HOME/rtx/config.toml`.
|
|
|
|
See <https://github.com/jdxcode/rtx#global-config-configrtxconfigtoml>
|
|
for details on supported values.
|
|
|
|
::: {.warning}
|
|
Modifying the `tools` section doesn't make RTX install them.
|
|
You have to manually run `rtx install` to install the tools.
|
|
:::
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."rtx/config.toml" = mkIf (cfg.settings != { }) {
|
|
source = tomlFormat.generate "rtx-settings" cfg.settings;
|
|
};
|
|
|
|
programs = {
|
|
bash.initExtra = mkIf cfg.enableBashIntegration ''
|
|
eval "$(${getExe cfg.package} activate bash)"
|
|
'';
|
|
|
|
zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
eval "$(${getExe cfg.package} activate zsh)"
|
|
'';
|
|
|
|
fish.interactiveShellInit = mkIf cfg.enableFishIntegration ''
|
|
${getExe cfg.package} activate fish | source
|
|
'';
|
|
};
|
|
};
|
|
}
|