mirror of
https://github.com/nix-community/home-manager
synced 2024-11-23 13:13:26 +00:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
70 lines
1.7 KiB
Nix
70 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.ledger;
|
|
|
|
cfgText = generators.toKeyValue {
|
|
mkKeyValue = key: value:
|
|
if isBool value then
|
|
optionalString value "--${key}"
|
|
else
|
|
"--${key} ${toString value}";
|
|
listsAsDuplicateKeys = true;
|
|
} cfg.settings;
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.ledger = {
|
|
enable =
|
|
mkEnableOption (lib.mdDoc "ledger, a double-entry accounting system");
|
|
|
|
package = mkPackageOptionMD pkgs "ledger" { };
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str (listOf str) ]);
|
|
default = { };
|
|
example = {
|
|
sort = "date";
|
|
date-format = "%Y-%m-%d";
|
|
strict = true;
|
|
file = [
|
|
"~/finances/journal.ledger"
|
|
"~/finances/assets.ledger"
|
|
"~/finances/income.ledger"
|
|
];
|
|
};
|
|
description = lib.mdDoc ''
|
|
Configuration written to {file}`$XDG_CONFIG_HOME/ledger/ledgerrc`.
|
|
See <https://www.ledger-cli.org/3.0/doc/ledger3.html#Detailed-Option-Description>
|
|
for explanation about possible values.
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
example = literalExpression ''
|
|
--sort date
|
|
--effective
|
|
--date-format %Y-%m-%d
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Extra configuration to add to
|
|
{file}`$XDG_CONFIG_HOME/ledger/ledgerrc`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."ledger/ledgerrc" =
|
|
mkIf (cfg.settings != { } || cfg.extraConfig != "") {
|
|
text = cfgText + cfg.extraConfig;
|
|
};
|
|
};
|
|
}
|