mirror of
https://github.com/nix-community/home-manager
synced 2024-11-23 13:13:26 +00:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
76 lines
1.9 KiB
Nix
76 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.jujutsu;
|
|
tomlFormat = pkgs.formats.toml { };
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.shikanime ];
|
|
|
|
options.programs.jujutsu = {
|
|
enable = mkEnableOption
|
|
(lib.mdDoc "a Git-compatible DVCS that is both simple and powerful");
|
|
|
|
package = mkPackageOptionMD pkgs "jujutsu" { };
|
|
|
|
settings = mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
user = {
|
|
name = "John Doe";
|
|
email = "jdoe@example.org";
|
|
};
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Options to add to the {file}`.jjconfig.toml` file. See
|
|
<https://github.com/martinvonz/jj/blob/main/docs/config.md>
|
|
for options.
|
|
'';
|
|
};
|
|
|
|
enableBashIntegration = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = lib.mdDoc "Whether to enable Bash integration.";
|
|
};
|
|
|
|
enableZshIntegration = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = lib.mdDoc "Whether to enable Zsh integration.";
|
|
};
|
|
|
|
enableFishIntegration = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = lib.mdDoc "Whether to enable Fish integration.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
home.file.".jjconfig.toml" = mkIf (cfg.settings != { }) {
|
|
source = tomlFormat.generate "jujutsu-config" cfg.settings;
|
|
};
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
|
|
source <(${pkgs.jujutsu}/bin/jj debug completion)
|
|
'';
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
source <(${pkgs.jujutsu}/bin/jj debug completion --zsh | sed '$d')
|
|
compdef _jj ${pkgs.jujutsu}/bin/jj
|
|
'';
|
|
|
|
programs.fish.interactiveShellInit = mkIf cfg.enableFishIntegration ''
|
|
${pkgs.jujutsu}/bin/jj debug completion --fish | source
|
|
'';
|
|
};
|
|
}
|