mirror of
https://github.com/nix-community/home-manager
synced 2024-12-21 02:23:16 +00:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
60 lines
1.3 KiB
Nix
60 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.pueue;
|
|
yamlFormat = pkgs.formats.yaml { };
|
|
configFile = yamlFormat.generate "pueue.yaml" cfg.settings;
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.AndersonTorres ];
|
|
|
|
options.services.pueue = {
|
|
enable = mkEnableOption "Pueue, CLI process scheduler and manager";
|
|
|
|
package = mkPackageOption pkgs "pueue" { };
|
|
|
|
settings = mkOption {
|
|
type = yamlFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
daemon = {
|
|
default_parallel_tasks = 2;
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/pueue/pueue.yml`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions =
|
|
[ (hm.assertions.assertPlatform "services.pueue" pkgs platforms.linux) ];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile =
|
|
mkIf (cfg.settings != { }) { "pueue/pueue.yml".source = configFile; };
|
|
|
|
systemd.user = {
|
|
services.pueued = {
|
|
Unit = {
|
|
Description = "Pueue Daemon - CLI process scheduler and manager";
|
|
};
|
|
|
|
Service = {
|
|
Restart = "on-failure";
|
|
ExecStart = "${cfg.package}/bin/pueued -v -c ${configFile}";
|
|
};
|
|
|
|
Install.WantedBy = [ "default.target" ];
|
|
};
|
|
};
|
|
};
|
|
}
|