mirror of
https://github.com/nix-community/home-manager
synced 2024-12-21 02:23:16 +00:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
81 lines
2 KiB
Nix
81 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.pantalaimon;
|
|
|
|
iniFmt = pkgs.formats.ini { };
|
|
in {
|
|
meta.maintainers = [ maintainers.jojosch ];
|
|
|
|
options = {
|
|
services.pantalaimon = {
|
|
enable = mkEnableOption
|
|
"Pantalaimon, an E2EE aware proxy daemon for matrix clients";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.pantalaimon;
|
|
defaultText = literalExpression "pkgs.pantalaimon";
|
|
description =
|
|
"Package providing the {command}`pantalaimon` executable to use.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = iniFmt.type;
|
|
default = { };
|
|
defaultText = literalExpression "{ }";
|
|
example = literalExpression ''
|
|
{
|
|
Default = {
|
|
LogLevel = "Debug";
|
|
SSL = true;
|
|
};
|
|
local-matrix = {
|
|
Homeserver = "https://matrix.org";
|
|
ListenAddress = "127.0.0.1";
|
|
ListenPort = 8008;
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/pantalaimon/pantalaimon.conf`.
|
|
|
|
See <https://github.com/matrix-org/pantalaimon/blob/master/docs/manpantalaimon.5.md> or
|
|
{manpage}`pantalaimon(5)`
|
|
for options.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.pantalaimon" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
systemd.user.services = {
|
|
pantalaimon = {
|
|
Unit = {
|
|
Description =
|
|
"Pantalaimon - E2EE aware proxy daemon for matrix clients";
|
|
After = [ "network-online.target" ];
|
|
};
|
|
|
|
Service = {
|
|
ExecStart = "${cfg.package}/bin/pantalaimon -c ${
|
|
iniFmt.generate "pantalaimon.conf" cfg.settings
|
|
}";
|
|
Restart = "on-failure";
|
|
};
|
|
|
|
Install.WantedBy = [ "default.target" ];
|
|
};
|
|
};
|
|
};
|
|
}
|