mirror of
https://github.com/nix-community/home-manager
synced 2024-11-27 07:00:48 +00:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
106 lines
2.9 KiB
Nix
106 lines
2.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.mangohud;
|
|
|
|
settingsType = with types;
|
|
(oneOf [ bool int float str path (listOf (oneOf [ int str ])) ]);
|
|
|
|
renderOption = option:
|
|
rec {
|
|
int = toString option;
|
|
float = int;
|
|
path = int;
|
|
bool = "false";
|
|
string = option;
|
|
list = concatStringsSep "," (lists.forEach option (x: toString x));
|
|
}.${builtins.typeOf option};
|
|
|
|
renderLine = k: v: (if isBool v && v then k else "${k}=${renderOption v}");
|
|
renderSettings = attrs:
|
|
strings.concatStringsSep "\n" (attrsets.mapAttrsToList renderLine attrs)
|
|
+ "\n";
|
|
|
|
in {
|
|
options = {
|
|
programs.mangohud = {
|
|
enable = mkEnableOption (lib.mdDoc "Mangohud");
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.mangohud;
|
|
defaultText = literalExpression "pkgs.mangohud";
|
|
description = lib.mdDoc "The Mangohud package to install.";
|
|
};
|
|
|
|
enableSessionWide = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Sets environment variables so that
|
|
MangoHud is started on any application that supports it.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf settingsType;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
output_folder = ~/Documents/mangohud/;
|
|
full = true;
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/MangoHud/MangoHud.conf`. See
|
|
<https://github.com/flightlessmango/MangoHud/blob/master/data/MangoHud.conf>
|
|
for the default configuration.
|
|
'';
|
|
};
|
|
|
|
settingsPerApplication = mkOption {
|
|
type = with types; attrsOf (attrsOf settingsType);
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
mpv = {
|
|
no_display = true;
|
|
}
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Sets MangoHud settings per application.
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/MangoHud/{application_name}.conf`. See
|
|
<https://github.com/flightlessmango/MangoHud/blob/master/data/MangoHud.conf>
|
|
for the default configuration.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(hm.assertions.assertPlatform "programs.mangohud" pkgs platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
home.sessionVariables = mkIf cfg.enableSessionWide {
|
|
MANGOHUD = 1;
|
|
MANGOHUD_DLSYM = 1;
|
|
};
|
|
|
|
xdg.configFile = {
|
|
"MangoHud/MangoHud.conf" =
|
|
mkIf (cfg.settings != { }) { text = renderSettings cfg.settings; };
|
|
} // mapAttrs'
|
|
(n: v: nameValuePair "MangoHud/${n}.conf" { text = renderSettings v; })
|
|
cfg.settingsPerApplication;
|
|
};
|
|
|
|
meta.maintainers = with maintainers; [ zeratax ];
|
|
}
|