mirror of
https://github.com/fish-shell/fish-shell
synced 2024-12-29 14:23:09 +00:00
55bc6a27c6
Commit5d135d555(prompts: fix pipestatus for jobs prefixed with "not") introduced a backwards compatibility hack about adding an optional argument to __fish_print_pipestatus. This hack would break downgrading to fish 3.1.2 if the user copied the new prompt to their config - they would get a backtrace on every prompt which is arguably worse than the patch's minor improvement. This does away with the error trace - old fish just won't show the fancy new pipestatus on `not true`. Implemented by passing the last $status as the poor man's kwarg, which works since 3.1.0 (9b86d5dd1Export all local exported variables in a new scope). The prompts don't work with fish 3.0.0 or older; downgrading does not seem too important in general but I think this patch is an okay simplification.
36 lines
1.5 KiB
Fish
36 lines
1.5 KiB
Fish
# name: Classic + Vcs (the default)
|
|
# author: Lily Ballard
|
|
|
|
function fish_prompt --description 'Write out the prompt'
|
|
set -l last_pipestatus $pipestatus
|
|
set -lx __fish_last_status $status # Export for __fish_print_pipestatus.
|
|
set -l normal (set_color normal)
|
|
|
|
# Color the prompt differently when we're root
|
|
set -l color_cwd $fish_color_cwd
|
|
set -l suffix '>'
|
|
if functions -q fish_is_root_user; and fish_is_root_user
|
|
if set -q fish_color_cwd_root
|
|
set color_cwd $fish_color_cwd_root
|
|
end
|
|
set suffix '#'
|
|
end
|
|
|
|
# If we're running via SSH, change the host color.
|
|
set -l color_host $fish_color_host
|
|
if set -q SSH_TTY
|
|
set color_host $fish_color_host_remote
|
|
end
|
|
|
|
# Write pipestatus
|
|
# If the status was carried over (e.g. after `set`), don't bold it.
|
|
set -l bold_flag --bold
|
|
set -q __fish_prompt_status_generation; or set -g __fish_prompt_status_generation $status_generation
|
|
if test $__fish_prompt_status_generation = $status_generation
|
|
set bold_flag
|
|
end
|
|
set __fish_prompt_status_generation $status_generation
|
|
set -l prompt_status (__fish_print_pipestatus "[" "]" "|" (set_color $fish_color_status) (set_color $bold_flag $fish_color_status) $last_pipestatus)
|
|
|
|
echo -n -s (set_color $fish_color_user) "$USER" $normal @ (set_color $color_host) (prompt_hostname) $normal ' ' (set_color $color_cwd) (prompt_pwd) $normal (fish_vcs_prompt) $normal " "$prompt_status $suffix " "
|
|
end
|