mirror of
https://github.com/fish-shell/fish-shell
synced 2024-12-25 20:33:08 +00:00
cb74f0f60e
https://www.freebsd.org/cgi/man.cgi?query=ssh_config&sektion=5 1. It is possible to add multiple whitespace characters between the keyword (i.e. Host) and the argument(s). 2. It is allowed to have a single = and whitespace between the keyword and the argument(s). 3. It is possible to add multiple host names under a single Host directive by spacing the names apart. 1. and 3. are actual conventions that we use in our team, and I couldn't get auto-complete working for fish without this modification. Modification explained: a. The space between Host(?:name)? and the \w.* was replaced by (?:\s+|\s*=\s*) to match any sequence of whitespace characters, or optional whitespaces with a single =, per spec. b. Result of first replacement is piped through another string replace to switch duplicate whitespace characters to a single space, and then piped to be split by that space. This allows specifying several aliases or host names in a single Host/Hostname definition, also per spec.
40 lines
1.7 KiB
Fish
40 lines
1.7 KiB
Fish
|
|
function __fish_print_hostnames -d "Print a list of known hostnames"
|
|
# HACK: This only deals with ipv4
|
|
|
|
# Print all hosts from /etc/hosts
|
|
if type -q getent
|
|
# Ignore zero ips
|
|
getent hosts | string match -r -v '^0.0.0.0' \
|
|
| string replace -r '[0-9.]*\s*' '' | string split " "
|
|
else if test -r /etc/hosts
|
|
# Ignore commented lines and functionally empty lines
|
|
string match -r -v '^\s*0.0.0.0|^\s*#|^\s*$' < /etc/hosts \
|
|
# Strip comments
|
|
| string replace -ra '#.*$' '' \
|
|
| string replace -r '[0-9.]*\s*' '' | string trim | string replace -ra '\s+' '\n'
|
|
end
|
|
|
|
# Print nfs servers from /etc/fstab
|
|
if test -r /etc/fstab
|
|
string match -r '^\s*[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3]:|^[a-zA-Z\.]*:' </etc/fstab | string replace -r ':.*' ''
|
|
end
|
|
|
|
# Check hosts known to ssh
|
|
set -l known_hosts ~/.ssh/known_hosts{,2} /etc/ssh/known_hosts{,2} # Yes, seriously - the default specifies both with and without "2"
|
|
for file in /etc/ssh/ssh_config ~/.ssh/config
|
|
if test -r $file
|
|
# Print hosts from system wide ssh configuration file
|
|
# Note the non-capturing group to avoid printing "name"
|
|
string match -ri '\s*Host(?:name)?(?:\s+|\s*=\s*)\w.*' < $file | string replace -ri '^\s*Host(?:name)?\s*(\S+)' '$1' \
|
|
| string replace -r '\s+' ' ' | string split ' '
|
|
set known_hosts $known_hosts (string match -ri '^\s*UserKnownHostsFile|^\s*GlobalKnownHostsFile' < $file \
|
|
| string replace -ri '.*KnownHostsFile\s*' '')
|
|
end
|
|
end
|
|
for file in $known_hosts
|
|
# Ignore hosts that are hashed, commented or have custom ports (like [localhost]:2200)
|
|
test -r $file; and string replace -ra '(\S+) .*' '$1' < $file | string match -r '^[^#|[=]+$' | string split ","
|
|
end
|
|
return 0
|
|
end
|