mirror of
https://github.com/fish-shell/fish-shell
synced 2025-01-15 06:24:01 +00:00
b56b230076
Reproducible at least on Linux, where the "named pipe" universal variable notifier is used: rm -rf build/test/xdg_config XDG_CONFIG_HOME=build/test/xdg_config ./build/fish -c "xterm -e ./build/fish" The child fish reacts to keyboard input with a noticeable initial delay. This is because the universal variable file is polled over a million times, even when I immediately press Control-D. This polling prevents readb() from handling keyboard input. Before commit939aba02d("Refactor input_common.cpp:readb"), readb() reacted to keyboard input even when there were universal variable notifications. Restore this behavior, but make sure to call the universal variable notifier after the new "prepare_to_select" logic. Maybe the problem is in the notifier but the old behavior was sane. Fixes the problems described in7a556ec6f2 (commitcomment-49773677)Adding "-d uvars-file" to the reproducesr shows that we are checking the uvar file repeatedly: uvar-file: universal log sync uvar-file: universal log sync elided based on fast stat() uvar-file: universal log no modifications
51 lines
1.4 KiB
Fish
51 lines
1.4 KiB
Fish
#RUN: %fish -C 'set -g fish %fish' %s
|
|
#REQUIRES: command -v tmux
|
|
# Don't run this on GitHub Actions since it's flaky.
|
|
#REQUIRES: test "$CI" != true
|
|
|
|
# Isolated tmux.
|
|
set -g tmpdir (mktemp -d)
|
|
set -g tmux tmux -S $tmpdir/.tmux-socket -f /dev/null
|
|
|
|
set -g sleep sleep .1
|
|
|
|
set fish (builtin realpath $fish)
|
|
cd $tmpdir
|
|
|
|
$tmux new-session -x 80 -y 10 -d $fish -C '
|
|
# This is similar to "tests/interactive.config".
|
|
function fish_greeting; end
|
|
function fish_prompt; printf "prompt $status_generation> "; end
|
|
# No autosuggestion from older history.
|
|
set fish_history ""
|
|
'
|
|
$sleep # Let fish draw a prompt.
|
|
|
|
# Don't escape existing token (#7526).
|
|
echo >file-1
|
|
echo >file-2
|
|
$tmux send-keys 'HOME=$PWD ls ~/' Tab
|
|
$sleep
|
|
$tmux capture-pane -p
|
|
# Note the contents may or may not have the autosuggestion appended - it is a race.
|
|
# CHECK: prompt 0> HOME=$PWD ls ~/file-{{1?}}
|
|
# CHECK: ~/file-1 ~/file-2
|
|
|
|
# No pager on single smartcase completion (#7738).
|
|
$tmux send-keys C-u C-l 'mkdir cmake CMakeFiles' Enter C-l \
|
|
'cat cmake' Tab
|
|
$sleep
|
|
$tmux capture-pane -p
|
|
# CHECK: prompt 1> cat cmake/
|
|
|
|
# Correct case in pager when prefixes differ in case (#7743).
|
|
$tmux send-keys C-u C-l 'complete -c foo2 -a "aabc aaBd" -f' Enter C-l \
|
|
'foo2 A' Tab
|
|
$sleep
|
|
$tmux capture-pane -p
|
|
# The "bc" part is the autosuggestion - we could use "tmux capture-pane -e" to check colors.
|
|
# CHECK: prompt 2> foo2 aabc
|
|
# CHECK: aabc aaBd
|
|
|
|
$tmux kill-server
|
|
rm -r $tmpdir
|