mirror of
https://github.com/fish-shell/fish-shell
synced 2024-12-26 04:43:10 +00:00
8f22def8f7
The recent change to switch `psub` to use `argparse` caused it to use a fifo by default because it inadvertently fixed a long standing bug in the fish script. This changes the behavior back to `psub --file` being the default behavior and introduces a `--fifo` flag. It also updates the documentation to make it clearer when and why `--fifo` mode should not be used. Fixes #4222
67 lines
1.9 KiB
Fish
67 lines
1.9 KiB
Fish
function psub --description "Read from stdin into a file and output the filename. Remove the file when the command that called psub exits."
|
|
set -l options -x 'f,F' -x 'F,s' 'h/help' 'f/file' 'F/fifo' 's/suffix=' 'T-testing'
|
|
argparse -n psub --max-args=0 $options -- $argv
|
|
or return
|
|
|
|
if set -q _flag_help
|
|
__fish_print_help psub
|
|
return 0
|
|
end
|
|
|
|
set -l dirname
|
|
set -l filename
|
|
set -l funcname
|
|
|
|
if not status --is-command-substitution
|
|
printf (_ "%s: Not inside of command substitution") psub >&2
|
|
return 1
|
|
end
|
|
|
|
set -l tmpdir /tmp
|
|
set -q TMPDIR
|
|
and set tmpdir $TMPDIR
|
|
|
|
if set -q _flag_fifo
|
|
# Write output to pipe. This needs to be done in the background so
|
|
# that the command substitution exits without needing to wait for
|
|
# all the commands to exit.
|
|
set dirname (mktemp -d $tmpdir/.psub.XXXXXXXXXX)
|
|
or return
|
|
set filename $dirname/psub.fifo"$_flag_suffix"
|
|
mkfifo $filename
|
|
cat >$filename &
|
|
else if test -z "$_flag_suffix"
|
|
set filename (mktemp $tmpdir/.psub.XXXXXXXXXX)
|
|
cat >$filename
|
|
else
|
|
set dirname (mktemp -d $tmpdir/.psub.XXXXXXXXXX)
|
|
set filename "$dirname/psub$_flag_suffix"
|
|
cat >$filename
|
|
end
|
|
|
|
# Write filename to stdout
|
|
echo $filename
|
|
|
|
# This flag isn't documented. It's strictly for our unit tests.
|
|
if set -q _flag_testing
|
|
return
|
|
end
|
|
|
|
# Find unique function name
|
|
while true
|
|
set funcname __fish_psub_(random)
|
|
if not functions $funcname >/dev/null ^/dev/null
|
|
break
|
|
end
|
|
end
|
|
|
|
# Make sure we erase file when caller exits
|
|
function $funcname --on-job-exit caller --inherit-variable filename --inherit-variable dirname --inherit-variable funcname
|
|
command rm $filename
|
|
if test -n "$dirname"
|
|
command rmdir $dirname
|
|
end
|
|
functions -e $funcname
|
|
end
|
|
|
|
end
|