mirror of
https://github.com/fish-shell/fish-shell
synced 2024-12-27 05:13:10 +00:00
3626c39398
I'm going to modify these functions as part of dealing with issue #3000 and don't want those changes to be masked by running the files through `make style`.
42 lines
918 B
Fish
42 lines
918 B
Fish
#
|
|
# Wrap the builtin cd command to maintain directory history.
|
|
#
|
|
function cd --description "Change directory"
|
|
set -l MAX_DIR_HIST 25
|
|
|
|
if test (count $argv) -gt 1
|
|
printf "%s\n" (_ "Too many args for cd command")
|
|
return 1
|
|
end
|
|
|
|
# Skip history in subshells.
|
|
if status --is-command-substitution
|
|
builtin cd $argv
|
|
return $status
|
|
end
|
|
|
|
# Avoid set completions.
|
|
set -l previous $PWD
|
|
|
|
if test "$argv" = "-"
|
|
if test "$__fish_cd_direction" = "next"
|
|
nextd
|
|
else
|
|
prevd
|
|
end
|
|
return $status
|
|
end
|
|
|
|
builtin cd $argv
|
|
set -l cd_status $status
|
|
|
|
if test $cd_status -eq 0 -a "$PWD" != "$previous"
|
|
set -q dirprev[$MAX_DIR_HIST]
|
|
and set -e dirprev[1]
|
|
set -g dirprev $dirprev $previous
|
|
set -e dirnext
|
|
set -g __fish_cd_direction prev
|
|
end
|
|
|
|
return $cd_status
|
|
end
|