mirror of
https://github.com/fish-shell/fish-shell
synced 2024-12-28 05:43:11 +00:00
1527edd542
When we want to print something while the prompt is still active, we move the
cursor by printing a newline for each line in the prompt beyond the first
one. As established by 80fe0a7fc (fish_job_summary: Format message better
for multiline prompts, 2022-06-28), our use of "string repeat" actually
prints an extra newline. Let's remove it here as well.
34 lines
969 B
Fish
34 lines
969 B
Fish
# This function is typically bound to Alt-W, it is used to list man page entries
|
|
# for the command under the cursor.
|
|
function __fish_whatis_current_token -d "Show man page entries or function description related to the token under the cursor"
|
|
set -l token (commandline -pt)
|
|
|
|
test -n "$token"
|
|
or return
|
|
|
|
printf "\n"
|
|
set -l desc "$token: nothing appropriate."
|
|
|
|
set -l tokentype (type --type $token 2>/dev/null)
|
|
|
|
switch "$tokentype"
|
|
case function
|
|
set -l funcinfo (functions $token --details --verbose)
|
|
|
|
test $funcinfo[5] != n/a
|
|
and set desc "$token - $funcinfo[5]"
|
|
|
|
case builtin
|
|
set desc (__fish_print_help $token | awk "/./ {print; exit}")
|
|
|
|
case file
|
|
set -l tmpdesc (whatis $token 2>/dev/null)
|
|
and set desc $tmpdesc
|
|
end
|
|
|
|
printf "%s\n" $desc
|
|
|
|
string repeat -N \n --count=(math (count (fish_prompt)) - 1)
|
|
|
|
commandline -f repaint
|
|
end
|