From e5b2c3e4be2aad31289c980fbb0f05a42ed9be11 Mon Sep 17 00:00:00 2001
From: Fabian Boehm <FHomborg@gmail.com>
Date: Tue, 16 Jan 2024 17:22:18 +0100
Subject: [PATCH] Add helper to cache `| source` completions

We have a lot of completions that look like

```fish
pip completion --fish 2>/dev/null | source
```

That's *fine*, upstream gives us some support.

However, the scripts they provide change very rarely, usually not even
every release, and so running them again for every shell is extremely
wasteful.

In particular the python tools are very slow, `pip completion --fish`
takes about 180ms on my system with a hot cache, which is quite
noticeable.

So what we do is we run them once, store them in a file in our cache
directory, and then serve from that.

We store the mtime of the command we ran, and compare against that for
future runs. If the mtime differs - so if the command was up or
downgraded, we run it again.
---
 .../__fish_cache_sourced_completions.fish     | 45 +++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 share/functions/__fish_cache_sourced_completions.fish

diff --git a/share/functions/__fish_cache_sourced_completions.fish b/share/functions/__fish_cache_sourced_completions.fish
new file mode 100644
index 000000000..41ba3bea9
--- /dev/null
+++ b/share/functions/__fish_cache_sourced_completions.fish
@@ -0,0 +1,45 @@
+function __fish_cache_sourced_completions
+    # Allow a `--name=foo` option which ends up in the filename.
+    argparse -s name= -- $argv
+    or return
+
+    set -q argv[1]
+    or return 1
+    
+    set -l cmd (command -s $argv[1])
+    or begin
+        # If we have no command, we can't get an mtime
+        # and so we can't cache
+        # The caller can more easily retry
+        return 127
+    end
+
+    set -l cachedir (__fish_make_cache_dir completions)
+    or return
+
+    set -l stampfile $cachedir/$argv[1].stamp
+    set -l compfile $cachedir/$argv[1].fish
+
+    set -l mtime (path mtime -- $cmd)
+
+    set -l cmtime 0
+    path is -rf -- $stampfile
+    and read cmtime < $stampfile
+
+    # If either the timestamp or the completion file don't exist,
+    # or the mtime differs, we rerun.
+    #
+    # That means we'll rerun if the command was up- or downgraded.
+    if path is -vrf -- $stampfile $compfile || test "$cmtime" -ne "$mtime" 2>/dev/null
+        $argv > $compfile
+        # If the command exited unsuccessfully, we assume it didn't work.
+        or return 2
+        echo -- $mtime > $stampfile
+    end
+
+    if path is -rf -- $compfile
+        source $compfile
+        return 0
+    end
+    return 3
+end