fish-shell/etc/fish.in

#
# Init file for fish
#
# @configure_input@

#
# Set default search paths
#

set -g fish_function_path ~/.fish.d/functions    @SYSCONFDIR@/fish.d/functions    @DATADIR@/fish/functions 
set -g fish_complete_path ~/.fish.d/completions  @SYSCONFDIR@/fish.d/completions  @DATADIR@/fish/completions 

#
# Set default field separators
#

set -g IFS \ \t\n

#
# Add a few common directories to path, if they exists. Note that pure
# console programs like makedep sometimes live in /usr/X11R6/bin, so we
# want this even for text-only terminals.
#

set -l path_list /bin /usr/bin /usr/X11R6/bin @PREFIX@/bin @optbindirs@

# Root should also have the sbin directories in the path
if test "$USER" = root
	set path_list $path_list /sbin /usr/sbin /usr/local/sbin
end

for i in $path_list
	if not expr "$PATH" : .\*$i.\* >/dev/null
		if test -d $i
			set PATH $PATH $i
		end
	end
end


#
# Set some value for LANG if nothing was set before, and this is a
# login shell. Also check for i18n information in /etc/sysconfig/i18n
#

if status --is-login
	if not set -q LANG >/dev/null
		set -gx LANG en_US.UTF-8
	end

	if test -f /etc/sysconfig/i18n
		eval (cat /etc/sysconfig/i18n |sed -ne 's/^\([a-zA-Z]*\)=\(.*\)$/set -gx \1 \2;/p')
	end
end

#
# Put linux console in unicode mode. Should this be done in any other
# situation as well?
#

if expr "$LANG" : ".*\.[Uu][Tt][Ff].*" >/dev/null
	if test linux = "$TERM"
		if which unicode_start >/dev/null
			unicode_start
		end
	end
end


#
# There are variables that contain colons that are not arrays. This 
# reverts them back to regular strings.
#

for i in DISPLAY
	if set -q $i
		set -- $i (printf ":%s" $$i|cut -c 2-)
	end
end

#
# Load additional initialization files
#

for i in fish.d/*.fish
	. $i
end